home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d12 / v10n22.arc / ATOI.ASM next >
Assembly Source File  |  1991-12-08  |  3KB  |  81 lines
  1.         title   ATOI - ASCII to integer
  2.         page    55,132
  3.  
  4. ; ATOI.ASM --- Convert ASCII string to 16-bit decimal integer.
  5. ;
  6. ; Copyright (C) 1989 Ray Duncan
  7. ; 
  8. ; Call with:    DS:SI = address of string,
  9. ;               where 'string' is in the form
  10. ;                  [whitespace][sign][digits]
  11. ;
  12. ; Returns:      AX    = result
  13. ;               DS:SI = address+1 of terminator 
  14. ;
  15. ; Destroys:     Nothing
  16. ;
  17. ; Like the C runtime library function 'atoi', this routine gives no 
  18. ; warning of overflow, and terminates on the first invalid character.
  19.  
  20. blank   equ     20h             ; ASCII blank character
  21. tab     equ     09h             ; ASCII tab character
  22.  
  23. _TEXT   segment word public 'CODE'
  24.  
  25.         assume  cs:_TEXT
  26.  
  27.         public  atoi
  28. atoi    proc    near
  29.  
  30.         push    bx                      ; save registers
  31.         push    cx
  32.         push    dx
  33.  
  34.         xor     bx,bx                   ; initialize forming answer
  35.         xor     cx,cx                   ; initialize sign flag
  36.  
  37. atoi1:  lodsb                           ; scan off whitespace
  38.         cmp     al,blank                ; ignore leading blanks
  39.         je      atoi1
  40.         cmp     al,tab                  ; ignore leading tabs
  41.         je      atoi1
  42.  
  43.         cmp     al,'+'                  ; if + sign, proceed
  44.         je      atoi2
  45.         cmp     al,'-'                  ; is it - sign?
  46.         jne     atoi3                   ; no, test if numeric
  47.         dec     cx                      ; was - sign, set flag
  48.                                         ; for negative result
  49.  
  50. atoi2:  lodsb                           ; get next character
  51.  
  52. atoi3:  cmp     al,'0'                  ; is character valid?
  53.         jb      atoi4                   ; jump if not '0' to '9'
  54.         cmp     al,'9'
  55.         ja      atoi4                   ; jump if not '0' to '9'
  56.  
  57.         and     ax,0fh                  ; isolate lower four bits
  58.  
  59.         xchg    bx,ax                   ; previous answer x 10
  60.         mov     dx,10
  61.         mul     dx
  62.  
  63.         add     bx,ax                   ; add this digit
  64.  
  65.         jmp     atoi2                   ; convert next digit
  66.  
  67. atoi4:  mov     ax,bx                   ; put result into AX
  68.         jcxz    atoi5                   ; jump if sign flag clear
  69.         neg     ax                      ; make result negative
  70.  
  71. atoi5:  pop     dx                      ; restore registers
  72.         pop     cx
  73.         pop     bx
  74.         ret                             ; back to caller
  75.  
  76. atoi    endp
  77.  
  78. _TEXT   ends
  79.  
  80.         end
  81.